推廣 熱搜： 集成  系統集成  弱電  軟件  kvm  服務器  思科  視頻會議  拼接  SFP 

適合程序員的智能家居

   日期：2014-06-19     來源：博客園    作者：SuperEVO    瀏覽：173    評論：0    
核心提示：看到最近智能家居的討論挺火，我也來分享下在智能家居這塊的體會。我主要改造了我租的房子的室燈。主要實現功能有：監控室內環境，改裝了室燈，光線暗的時候有人時自動開燈，光線亮自動滅燈,可紅外用遙控器、手機客戶端改變閾值。

看到最近智能家居的討論挺火，我也來分享下在智能家居這塊的體會。我主要改造了我租的房子的室燈。主要實現功能有：監控室內環境，改裝了室燈，光線暗的時候有人時自動開燈，光線亮自動滅燈,可紅外用遙控器、手機客戶端改變閾值。

材料

主控板：Arduino UNO/Mega2560（IO口多）

傳感器：光敏電阻、DHT11溫濕度傳感器、串口WIFI模塊、紅外遙控探頭、紅外人體探測器、5V繼電器（220V）

布線

室燈控制還是很簡單的，控制電源即可。

  • 首先使用繼電器接管室燈的電線。
  • 然后放置紅外人體探測器，我把它朝向房間門口。
  • 溫濕度傳感器、光敏電阻、wifi模塊、紅外遙控探頭就比較隨意了，合理放置就行。

程序開發

Arduino開發工具官方有提供，代碼類似c語言，有很多第三方庫，開發非常容易。最讓我感到幸福的是VS也有相應的開發環境，有個插件叫做Visual Micro。

  • 控制電路無非就是置數字IO口高電平或低電平。
  • 光敏電阻測光很簡單，使用模擬口測電阻值，如果需要精度更高更專業的可以買專門的測光模塊。
  • 通信方式多種多樣，紅外遙控、射頻、藍牙、wifi，坑爹的wp不支持藍牙串口，所以我選用的是串口wifi，使用簡單，模塊有自己的配置頁面，我配置成接入屋里的wifi網絡+模塊自建AP，并使用UDP模式發送廣播。
  • 具體代碼附在下面。

原型

原型

可以使用220v~5v變壓器，這樣就可以把主體放到燈罩里了，而且可以使用小點的板子。

擴展

Arduino這種類似積木的搭建方法非常適合咱們程序員自己DIY，不需要自己制作電路板。在這個室燈控制的基礎上咱們在擴展一下思維：

  • 加上紅外發射頭就可以控制相應的紅外遙控設備，一個接收一個發射組合就是萬能遙控器，多個發射器可以防死角
  • 加上常用的2.4G或者低頻段的無線模塊，就可以實現無線設備間通訊（模塊很便宜，有興趣可以嘗試鼠標、鍵盤、遙控車、航模通訊）
  • 加個舵機，拉窗簾不在話下。
  • 再大膽點，拆開電器找到電路板，接上線，使用Arduino的數字IO直接監控/控制電器電路板。
  • 加上語音識別模塊（目前的貌似都不太理想，相對Arduino有些重，這活交給家庭網關或者手機比較好）語音控制電器。

Arduino可以方便的實現控制電源、控制/監控帶電路控制的電器的電路板。

憧憬一下當WP的Cortana成熟的時候，這些設備控制，Cortana都能根據我的習慣自動搞定，并支持語音控制，全時待命，未來生活啊~

最后附上我的Arduino代碼：

  1. #include <EEPROM.h>  
  2. #include <IRremote.h>  
  3. #include <dht11.h>  
  4.    
  5. //UNO  
  6. //#define GM_dpin A5             //光敏電阻  
  7. //#define dht_dpin 2            //溫濕度傳感器  
  8. //#define wifiRx_dpin 5            //WIFI接收Rx  
  9. //#define wifiTx_dpin 6            //WIFI發送Tx  
  10. //#define HW_dpin 8                //紅外遙控探頭  
  11. //#define RSensor_dpin 10        //紅外探測器人  
  12. //#define jdq_dpin 11            //繼電器  
  13. //#define light_dpin 13            //指示燈  
  14.    
  15. //2560  
  16. #define GM_dpin A15             //光敏電阻  
  17. //#define wifiTx_dpin 10        //WIFI發送Rx  
  18. //#define wifiRx_dpin 11        //WIFI接收Tx  
  19. #define dht_dpin 21                //溫濕度傳感器  
  20. #define HW_dpin 22                //紅外遙控探頭  
  21. #define RSensor_dpin 23            //紅外探測器人  
  22. #define jdq_dpin 29                //繼電器  
  23. #define light_dpin 13            //指示燈  
  24.    
  25. int ADZ = 45;                //暗度閥值  
  26. int LDZ = 175;                //亮度閥值  
  27.    
  28. bool IsJDQOpend = false;  
  29. bool IsAutoOpen = false;  
  30. bool IsPause = false;  
  31.    
  32. IRrecv irrecv(HW_dpin);  
  33. decode_results results;  
  34.    
  35. dht11 DHT;  
  36.    
  37. //SoftwareSerial WiFiPort(wifiRx_dpin, wifiTx_dpin);  
  38.    
  39. void InitController(){  
  40.     pinMode(jdq_dpin, OUTPUT);  
  41.     digitalWrite(jdq_dpin, LOW);  
  42.    
  43.     pinMode(light_dpin, OUTPUT);  
  44.     digitalWrite(light_dpin, LOW);  
  45.    
  46.     pinMode(RSensor_dpin, INPUT);  
  47.     pinMode(GM_dpin, INPUT);  
  48. }  
  49.    
  50. void closeLight(){  
  51.     digitalWrite(light_dpin, LOW);  
  52.     digitalWrite(jdq_dpin, LOW);  
  53.     IsJDQOpend = false;  
  54.     IsAutoOpen = false;  
  55.     delay(2000);  
  56. }  
  57.    
  58. void openLight(){  
  59.     digitalWrite(light_dpin, HIGH);  
  60.     digitalWrite(jdq_dpin, HIGH);  
  61.     IsJDQOpend = true;  
  62.     delay(2000);  
  63. }  
  64.    
  65. void makePause(){  
  66.     IsPause = !IsPause;  
  67.     if (IsPause){  
  68.         for (int i = 0; i < 5; i++)  
  69.         {  
  70.             digitalWrite(light_dpin, HIGH);  
  71.             delay(100);  
  72.             digitalWrite(light_dpin, LOW);  
  73.             delay(100);  
  74.         }  
  75.     }  
  76.     else{  
  77.         digitalWrite(light_dpin, HIGH);  
  78.         delay(1000);  
  79.         digitalWrite(light_dpin, LOW);  
  80.     }  
  81. }  
  82.    
  83. //室燈控制器  
  84. void LightController(){  
  85.     //接收紅外遙控器信號  
  86.     if (irrecv.decode(&results)) {  
  87.         Serial.println(results.value, HEX);  
  88.         if (results.value == 0xFFA25D){  
  89.             //關燈  
  90.             closeLight();  
  91.         }  
  92.         if (results.value == 0xFFE21D){  
  93.             //開燈  
  94.             openLight();  
  95.         }  
  96.         if (results.value == 0xFFC23D){  
  97.             //暫停  
  98.             makePause();  
  99.         }  
  100.         irrecv.resume();  
  101.     }  
  102.    
  103.     if (IsPause)return;  
  104.     //光敏電阻判斷室內亮度  
  105.     int valx = analogRead(GM_dpin);  
  106.     //Serial.println(valx);  
  107.     if (valx < ADZ){  
  108.         //繼電器如果是關的  
  109.         if (!IsJDQOpend){  
  110.             //紅外人體檢測  
  111.             int val = digitalRead(RSensor_dpin);  
  112.             if (val == 1)  
  113.             {  
  114.                 //開燈  
  115.                 openLight();  
  116.                 IsAutoOpen = true;  
  117.             }  
  118.             else 
  119.             {  
  120.                 return;  
  121.             }  
  122.         }  
  123.     }  
  124.     else{  
  125.         if (valx > LDZ && IsJDQOpend && IsAutoOpen){  
  126.             valx = analogRead(GM_dpin);  
  127.             if (valx <= LDZ)return;  
  128.             //環境亮，關燈  
  129.             closeLight();  
  130.         }  
  131.     }  
  132. }  
  133.    
  134. void setup(){  
  135.     byte    value = EEPROM.read(1);  
  136.     if (value != 255)ADZ = value;  
  137.    
  138.     value = EEPROM.read(2);  
  139.     if (value != 255)LDZ = value;  
  140.    
  141.     Serial.begin(115200);  
  142.     Serial3.begin(115200);  
  143.     InitController();  
  144.     irrecv.enableIRIn();  
  145.     delay(500);  
  146.     Serial.println();  
  147.     Serial.println("[---ZZY Hareware Startup---]");  
  148. }  
  149.    
  150. void loop(){  
  151.     LightController();  
  152.     InfoQuery();  
  153.     GetCommand();  
  154. }  
  155.    
  156. long timespan;  
  157. void InfoQuery(){  
  158.     unsigned long t = (micros() - timespan) / 1000000;  
  159.     if (t < 1)return;  
  160.     timespan = micros();  
  161.     //信息查詢  
  162.     //光控信息  
  163.     int valx = analogRead(GM_dpin);  
  164.     //溫濕度傳感器  
  165.     DHT.read(dht_dpin);  
  166.     String msg = "VMZClub_Home HTP H";  
  167.     msg += DHT.humidity;  
  168.     msg += "T";  
  169.     msg += DHT.temperature;  
  170.     msg += "L";  
  171.     msg += valx;  
  172.     msg += "S";  
  173.     msg += IsJDQOpend;  
  174.     msg += "P";  
  175.     msg += IsPause;  
  176.     msg += "F";  
  177.     msg += ADZ;  
  178.     msg += "/";  
  179.     msg += LDZ;  
  180.     Serial3.print(msg);  
  181.     Serial.println(msg);  
  182. }  
  183.    
  184. void GetCommand(){  
  185.     int cmd[10] = { -1 };  
  186.     for (int i = 0; i < 10; i++)  
  187.     {  
  188.         cmd[i] = Serial3.read();  
  189.         if (cmd[i] == -1)break;  
  190.         Serial.println((char) cmd[i]);  
  191.     }  
  192.     if (cmd[0] == -1)return;  
  193.     switch ((char) cmd[0])  
  194.     {  
  195.     case 'L':  
  196.         switch (cmd[1])  
  197.         {  
  198.         case '0':  
  199.             closeLight();  
  200.             break;  
  201.    
  202.         case '1':  
  203.             openLight();  
  204.             break;  
  205.         }  
  206.         break;  
  207.    
  208.     case 'P':  
  209.         switch (cmd[1])  
  210.         {  
  211.         case '0':  
  212.             IsPause = false;  
  213.             break;  
  214.    
  215.         case '1':  
  216.             IsPause = true;  
  217.             break;  
  218.         }  
  219.         break;  
  220.    
  221.     case 'F':  
  222.         switch (cmd[1])  
  223.         {  
  224.         case'A':  
  225.             if (cmd[2] != -1)    {  
  226.                 ADZ = cmd[2];  
  227.                 EEPROM.write(1, ADZ);  
  228.             }  
  229.             break;  
  230.         case'L':  
  231.             if (cmd[2] != -1){  
  232.                 LDZ = cmd[2];  
  233.                 EEPROM.write(2, LDZ);  
  234.             }  
  235.             break;  
  236.         }  
  237.         break;  
  238.     }  
  239. } 

本文來自：http://www.cnblogs.com/zhang740/p/3785600.html

 
標簽： 智能家居
打賞
 
更多>同類資訊
0 條相關評論

 
推薦資訊
點擊排行
?
網站首頁  |  付款方式  |  版權隱私  |  使用協議  |  聯系方式  |  關于我們  |  網站地圖  |  排名推廣  |  廣告服務  |  RSS訂閱  |  違規舉報  |  京ICP備11008917號-2  | 
 
porn视频在线观看